Username: Password: Remember me
# Maintainer: Muflone http://www.muflone.com/contacts/english/
 
pkgname=4kstogram
pkgver=2.1.0.1115
pkgrel=1
pkgdesc="Download and backup Instagram photos shared by any user."
arch=('i686' 'x86_64')
url="http://www.4kdownload.com/products/product-stogram"
screenshot="https://static.4kdownload.com/main/img/screenshots/stogram/hero-windows.png?9d0fdda500a6"
license=('custom:eula')
depends=('qt5-script' 'qt5-quickcontrols' 'libexif')
source=("http://downloads.4kdownload.com/app/${pkgname}_${pkgver%.*.*}_amd64.tar.bz2"
        "${pkgname}.desktop"
        "${pkgname}.png")
md5sums=('04c42830b4e848d5c43b980d4b755408'
         'e6169b31bbe2d998fc7776432705b23a'
         '94d1940d244688674fb4e6dc66bddf60')
 
package() {
  # Install desktop file
  install -m 755 -d "${pkgdir}/usr/share/applications"
  install -m 755 -t "${pkgdir}/usr/share/applications" "${pkgname}.desktop"
  # Install icon file
  install -m 755 -d "${pkgdir}/usr/share/pixmaps"
  install -m 644 -t "${pkgdir}/usr/share/pixmaps" "${pkgname}.png"
  # Install files
  cd "${pkgname}"
  install -m 755 -d "${pkgdir}/usr/lib/${pkgname}"
  install -m 755 -t "${pkgdir}/usr/lib/${pkgname}" "${pkgname}-bin"
  install -m 755 -d "${pkgdir}/usr/lib/${pkgname}/translation"
  install -m 755 -t "${pkgdir}/usr/lib/${pkgname}/translation" translation/*
  # Install launcher file
  install -m 755 -d "${pkgdir}/usr/bin"
  ln -s "/usr/lib/${pkgname}/${pkgname}-bin" "${pkgdir}/usr/bin/${pkgname}"
  # Install license file
  install -m 755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  install -m 644 -t "${pkgdir}/usr/share/licenses/${pkgname}" "doc/eula"
}