Username: Password: Remember me
# Forked from https://aur.archlinux.org/cgit/aur.git/tree/PKGBUILD?h=4kvideodownloader&id=0efef75855a34f0487b97150b8d6e5565d296476
 
pkgname=4kvideodownloader
pkgver=4.1.2.2075
pkgrel=1
pkgdesc="Quickly download videos from YouTube in high-quality."
arch=('x86_64')
url="http://www.4kdownload.com/products/product-videodownloader"
screenshot="https://static.4kdownload.com/main/img/screenshots/videodownloader/3-windows.d8c1e3d19ee4.png"
license=('custom:eula')
depends=('qt5-script' 'portaudio' 'ffmpeg')
source=("http://downloads.4kdownload.com/app/${pkgname}_${pkgver%.*.*}_amd64.tar.bz2"
        "${pkgname}.desktop"
        "${pkgname}.png")
md5sums=('0a081aba55d326c5ce6ac11bfd7f05ce'
         '4a92ff6032ed63200e6d38ad6d260830'
         '07a3760b1a475387376c0ee50da6d0b1')
 
package() {
  # Install desktop file
  install -m 755 -d "${pkgdir}/usr/share/applications"
  install -m 755 -t "${pkgdir}/usr/share/applications" "${pkgname}.desktop"
  # Install icon file
  install -m 755 -d "${pkgdir}/usr/share/pixmaps"
  install -m 644 -t "${pkgdir}/usr/share/pixmaps" "${pkgname}.png"
  # Install files
  cd "${pkgname}"
  install -m 755 -d "${pkgdir}/usr/lib/${pkgname}"
  install -m 755 -t "${pkgdir}/usr/lib/${pkgname}" "${pkgname}-bin"
  install -m 755 -d "${pkgdir}/usr/lib/${pkgname}/audio"
  install -m 755 -t "${pkgdir}/usr/lib/${pkgname}/audio" audio/*
  install -m 755 -d "${pkgdir}/usr/lib/${pkgname}/translation"
  install -m 755 -t "${pkgdir}/usr/lib/${pkgname}/translation" translation/*
  # Install launcher file
  install -m 755 -d "${pkgdir}/usr/bin"
  ln -s "/usr/lib/${pkgname}/${pkgname}-bin" "${pkgdir}/usr/bin/${pkgname}"
  # Install license file
  install -m 755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  install -m 644 -t "${pkgdir}/usr/share/licenses/${pkgname}" "doc/eula"
}