Username: Password: Remember me
pkgname=android-studio
pkgver=4.1.1.0
pkgrel=1
_build=201.6953283
pkgdesc="The official Android IDE (Stable branch)"
arch=('x86_64')
url="http://tools.android.com/"
screenshot="https://developer.android.com/studio/images/studio-homepage-hero.jpg"
license=('Apache')
makedepends=('unzip')
depends=('alsa-lib' 'freetype2' 'libxrender' 'libxtst')
optdepends=('gtk2: GTK+ look and feel'
            'libgl: emulator support')
options=('!strip')
source=("https://redirector.gvt1.com/edgedl/android/studio/ide-zips/$pkgver/android-studio-ide-$_build-linux.tar.gz"
        "$pkgname.desktop"
        "license.html")
sha256sums=('68032184959c54576f119b7c7c8ded175d848374f3954fa450530d78260dd68b'
            '73cd2dde1d0f99aaba5baad1e2b91c834edd5db3c817f6fb78868d102360d3c4'
            '7c0863b3840c7ed53cbef0054d781ddc81994ddac9cc60a56ceb95fc88a70b86')
 
package() {
  cd $pkgname
 
  # Install the application
  install -d $pkgdir/{opt/$pkgname,usr/bin}
  cp -a bin lib jre plugins license LICENSE.txt build.txt product-info.json $pkgdir/opt/$pkgname
  ln -s /opt/android-studio/bin/studio.sh $pkgdir/usr/bin/$pkgname
 
  # Copy licenses
  install -Dm644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.txt"
  install -Dm644 $srcdir/license.html "${pkgdir}/usr/share/licenses/${pkgname}/license.html"
 
  # Add the icon and desktop file
  install -Dm644 bin/studio.png $pkgdir/usr/share/pixmaps/$pkgname.png
  install -Dm644 $srcdir/$pkgname.desktop $pkgdir/usr/share/applications/$pkgname.desktop
 
  chmod -R ugo+rX $pkgdir/opt
}