Username: Password: Remember me
# Maintainer: Francesco Marinucci <franzmari [at] chakralinux [dot] org>
# Arch Maintainer: twa022 <twa022 at gmail dot com>
 
pkgname=audacious
pkgver=4.0
pkgrel=1
pkgdesc="Lightweight, advanced audio player (with qt5 interface)"
arch=('x86_64')
url="http://audacious-media-player.org/"
license=('BSD')
depends=('qt5-base' 'libguess' 'libsm' 
         'hicolor-icon-theme' 'desktop-file-utils')
makedepends=('python3' # for gdbus-codegen
             'audacious-plugins') 
optdepends=('unzip: zipped skins support')
provides=("${pkgname}=${pkgver}")
conflicts=('audacious-qt5')
replaces=('audacious-qt5')
source=(http://distfiles.audacious-media-player.org/$pkgname-$pkgver.tar.bz2)
sha256sums=('3f46025334cc79332ef87a0c94297632f8eceb8e1497bf5a76a57003453c8bea')
 
build() {
  cd $pkgname-$pkgver
 
  ./configure \
    --prefix=/usr \
    --with-buildstamp='Chakra Linux'
  make
}
 
package() {
  cd $pkgname-$pkgver
  make DESTDIR=$pkgdir install
  install -Dm644 COPYING $pkgdir/usr/share/licenses/$pkgname/LICENSE
}