Username: Password: Remember me
# Maintainer: FranzMari <franzmari [at] chakralinux [dot] org>
# Arch Maintainer: twa022 <twa022 at gmail dot com>
 
pkgname=audacious-plugins
pkgver=4.0
pkgrel=1
pkgdesc="Plugins for Audacious (qt5 interface)"
arch=('x86_64')
url="http://audacious-media-player.org/"
license=('BSD' 'GPL')
 
makedepends=("audacious>=$pkgver" 'qt5-multimedia'
             'glib2' 'python2' # for gdbus-codegen
             'alsa-lib' 'pulseaudio' 'jack2' 'lame' 'libvorbis' 'flac'
             'mpg123' 'faad2' 'ffmpeg' 'libmodplug' 'fluidsynth' 'libcdio-paranoia' #'libsidplayfp' 
             'wavpack' 'dbus-glib' 'libnotify' 'lirc' 'curl' 'libmtp'
             'neon' 'libmms' 'libcue')
 
optdepends=('alsa-lib: Advanced Linux Sound Arch. output'
            'pulseaudio: PulseAudio output'
            'jack2: Jack Audio Connection Kit output'
            'lame: FileWriter MP3 output'
            'libvorbis: Vorbis input, FileWriter Vorbis output'
            'flac: FLAC input, FileWriter FLAC output'
 
            'mpg123: MP3 input'
            'faad2: AAC input'
            'ffmpeg: ffaudio input'
            'libmodplug: modplug input'
            'fluidsynth: MIDI FluidSynth backend input'
            'libcdio-paranoia: CD Digital Audio input'
            'libsidplayfp: Commodore 64 audio input'
            'wavpack: WavPack input'
 
            'dbus-glib: Gnome Shortcuts Plugin'
            'libnotify: libnotify OSD'
            'lirc: LIRC'
            'curl: AudioScrobbler Client'
            'libmtp: Upload to MTP device'
 
            'neon: neon-based http transport'
            'libmms: libmms-based mms transport'
            'libcue: CUE playlist format'
 
            'qt5-multimedia: qtaudio support')
 
provides=("$pkgname=$pkgver")
conflicts=("$pkgname")
replaces=("$pkgname")
source=(http://distfiles.audacious-media-player.org/$pkgname-$pkgver.tar.bz2)
sha256sums=('e1ad3223c7833f167642563f3c30c68d292b1a457c9f0159fdedd58e575e3ee4')
 
build() {
  cd $pkgname-$pkgver
 
  ./configure \
    --prefix=/usr \
    --enable-amidiplug
  make
}
 
package() {
  cd $pkgname-$pkgver
  make DESTDIR=$pkgdir install
  install -Dm644 COPYING $pkgdir/usr/share/licenses/$pkgname/LICENSE
}