Username: Password: Remember me
# Maintainer: Francesco Marinucci <franzmari [at] chakralinux [dot] org>
# Arch Maintainer: twa022 <twa022 at gmail dot com>
 
_pkgname=audacious
pkgname=${_pkgname}-qt5
pkgver=3.10.1
pkgrel=1
pkgdesc="Lightweight, advanced audio player (with qt5 interface)"
arch=('x86_64')
url="http://audacious-media-player.org/"
license=('BSD')
depends=('qt5-base' 'libguess' 'libsm' 
         'hicolor-icon-theme' 'desktop-file-utils')
makedepends=('python2') # for gdbus-codegen
optdepends=('unzip: zipped skins support'
            'audacious-plugins-qt5: many helpful plugins')
provides=("${_pkgname}=${pkgver}")
conflicts=('audacious')
replaces=('audacious')
source=(http://distfiles.audacious-media-player.org/$_pkgname-$pkgver.tar.bz2)
install=$pkgname.install
sha256sums=('8366e840bb3c9448c2cf0cf9a0800155b0bd7cc212a28ba44990c3d2289c6b93')
 
build() {
  cd $_pkgname-$pkgver
 
  ./configure \
    --prefix=/usr \
    --with-buildstamp='Chakra Linux' \
    --enable-qt \
    --disable-gtk
  make
}
 
package() {
  cd $_pkgname-$pkgver
  make DESTDIR=$pkgdir install
  install -Dm644 COPYING $pkgdir/usr/share/licenses/$_pkgname/LICENSE
}