Username: Password: Remember me
# Maintainer:  danyf90 <daniele.formichelli@gmail.com>
# Contributor: Daniel Isenmann <daniel@archlinux.org>
 
pkgname=gimp
pkgver=2.8.4
_pkgver=2.8
pkgrel=2
pkgdesc="GNU Image Manipulation Program"
arch=('x86_64')
url="http://www.gimp.org/"
license=('GPL' 'LGPL')
depends=('pygtk' 'lcms' 'libxpm' 'libwmf' 'libxmu' 'librsvg' 'libmng' 'dbus-glib' 'libexif' 'gegl' 'jasper' 'desktop-file-utils' 'hicolor-icon-theme')
makedepends=('intltool' 'libwebkit-gtk2' 'poppler-glib' 'alsa-lib' 'iso-codes' 'curl' 'ghostscript')
optdepends=('gutenprint: for sophisticated printing only as gimp has built-in cups print support' 'libwebkit: for the help browser' 'poppler-glib: for pdf support' 'alsa-lib: for MIDI event controller module' 'curl: for URI support' 'ghostscript: for postscript support')
options=('!libtool' '!makeflags')
conflicts=('gimp-devel')
install=gimp.install
source=("ftp://ftp.gimp.org/pub/gimp/v${_pkgver}/${pkgname}-${pkgver}.tar.bz2" "gimp.desktop" "linux.gpl")
md5sums=('392592e8755d046317878d226145900f' 'fb04df33f0f36f893424a0d463e45690' 'bb27bc214261d36484093e857f015f38')
 
 
 
build() {
  cd $srcdir/$pkgname-$pkgver
  PYTHON=/usr/bin/python2 ./configure --prefix=/usr --sysconfdir=/etc --enable-mp --enable-gimp-console --enable-python --with-gif-compression=lzw --with-libcurl --without-aa --without-hal --without-gvfs --without-gnomevfs
  make
}
 
package() {
  cd $srcdir/$pkgname-$pkgver
  make DESTDIR=$pkgdir install
  sed -i 's|#!/usr/bin/env python|#!/usr/bin/env python2|' $pkgdir/usr/lib/gimp/2.0/plug-ins/*.py
  install -D -m644 $srcdir/linux.gpl $pkgdir/usr/share/gimp/2.0/palettes/Linux.gpl
 
  rm $pkgdir/usr/share/man/man1/gimp-console.1
  ln -sf gimp-console-$_pkgver.1.gz $pkgdir/usr/share/man/man1/gimp-console.1.gz
  ln -sf gimprc-$pkgver.5.gz        $pkgdir/usr/share/man/man5/gimprc.5.gz
  ln -sf gimptool-2.0.1.gz          $pkgdir/usr/share/man/man1/gimptool.1.gz
  ln -s  gimp-$pkgver.1.gz          $pkgdir/usr/share/man/man1/gimp.1.gz
# ln -s  gimptool-2.0               $pkgdir/usr/bin/gimptool
  cp $srcdir/gimp.desktop           $pkgdir/usr/share/applications
}