Username: Password: Remember me
# $Id$
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer: Jan "heftig" Steffens <jan.steffens@gmail.com>
# Contributor: farid <farid at archlinuc-br.org>
# Contributor: Archie <Mymaud@gmail.com>
 
pkgname=gmic
pkgdesc="GREYC's Magic Image Converter: image processing framework and GIMP plugin."
pkgver=2.3.2
pkgrel=1
arch=("x86_64")
url="http://gmic.sourceforge.net"
license=("custom:CeCILL")
makedepends=('fftw' 'openexr' 'opencv' 'hdf5')
depends=("fftw" "libtiff" "libjpeg" "libpng" "openexr" "libx11" "gimp" "qt5-base")
replaces=("greycstoration" "gimp-plugin-greycstoration" "gimp-plugin-gmic4gimp")
source=("http://gmic.eu/files/source/gmic_$pkgver.tar.gz")
md5sums=('fb277a25a2a02f25b842f3362ef81477')
 
build() {
  cd gmic-$pkgver
  make -C src cli lib libc WGET=/bin/true
 
  cd gmic-qt
  qmake-qt5 GMIC_PATH=../src GMIC_DYNAMIC_LINKING=on HOST=gimp
  make
}
 
package() {
 
 
  cd gmic-$pkgver/src
  make  DESTDIR=$pkgdir install
 
  cd ..
  install -Dm644 COPYING $pkgdir/usr/share/licenses/$pkgname/LICENSE
  install -Dm755 gmic-qt/gmic_gimp_qt $pkgdir/usr/lib/gimp/2.0/plug-ins/gmic_gimp
}