# Maintainer: Jose Riha <jose1711 gmail com>
# Maintainer: Julien Taverna <jujudusud gmail com>
# Contributor: Facundo G. Adorno <adorno.facundo gmail com>
 
pkgname=jamulus
_pkgname=Jamulus
pkgver=3.5.9
pkgrel=1
pkgdesc="Internet jam session software"
arch=('x86_64')
url='http://llcon.sourceforge.net/'
screenshot='http://llcon.sourceforge.net/images/Jamulus_small.png'
license=('GPL2')
depends=('glibc' 'gcc-libs' 'qt5-base')
makedepends=('jack')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/corrados/jamulus/archive/r${pkgver//./_}.tar.gz"
        "${pkgname}.desktop")
 
build() {
  cd "${srcdir}/${pkgname}-r${pkgver//./_}"
  qmake-qt5 Jamulus.pro
  make clean
  make
}
 
package() {
  cd "${srcdir}/${pkgname}-r${pkgver//./_}"
  install -Dm755 Jamulus "${pkgdir}/usr/bin/jamulus"
  install -Dm644 ${srcdir}/${pkgname}.desktop "${pkgdir}/usr/share/applications/jamulus.desktop"
  install -Dm644 src/res/fronticon.png "${pkgdir}/usr/share/pixmaps/jamulus.png"
  install -vDm 644 {ChangeLog,README.md} -t "${pkgdir}/usr/share/doc/${pkgname}"
}
 
sha1sums=('c1af4df511cbcc3b788871347be7a9e7cb866ce5'
          '11507b13c0c272238508ec51a863aded004a8b78')