Username: Password: Remember me
# Maintainer: Frankes <frankes dot glasir dot de>
# Contributor: Antonio Rojas <arojas@archlinux.org>
# Contributor: Lukas Jirkovsky <l.jirkovsky@gmail.com>
# Contributor: BlackEagle < ike DOT devolder AT gmail DOT com >
# Contributor: Dany Martineau <dany.luc.martineau at gmail.com>
# Contributor: Dylon Edwards <deltaecho@archlinux.us>
 
pkgname=kcm-wacomtablet
pkgver=3.2.0
pkgrel=3
epoch=1
pkgdesc="KDE GUI for the Wacom Linux Drivers"
arch=(x86_64)
url="https://cgit.kde.org/wacomtablet.git"
license=(GPL)
depends=(xf86-input-wacom plasma-workspace)
makedepends=(extra-cmake-modules kdoctools)
source=("https://download.kde.org/stable/wacomtablet/$pkgver/wacomtablet-$pkgver.tar.xz"{,.sig}
        "add_missing_includes.diff")
sha256sums=('c80ce63a41f6fcbb50ac4c2130ed2f8273c4b744e62e33d4b714bf83e8e5f7a4'
            'SKIP'
            '143b2e81e5152c2f1db6e03089b32d9b9fdf1e61739743179b0efb299eb5b44d')
validpgpkeys=('E6E4C916590026E45836A12EA8896AFDFEF5DF53') # Valeriy Malov
 
prepare() {
  mkdir -p build
 
  cd wacomtablet-$pkgver
  patch -Np1 < "$srcdir/add_missing_includes.diff"
}
 
build() {
  cd build
  cmake ../wacomtablet-$pkgver
  make
}
 
package() {
  cd build
  make DESTDIR="$pkgdir" install
}