Username: Password: Remember me
# Maintainer: Marco <marcomania at home dot se>
 
pkgname=libvorbis-aotuv
pkgver=b6.03
pkgrel=6
_releasedate=20110424
pkgdesc="A fork of libvorbis which improves its quality especially at lower bitrates"
url="http://www.geocities.jp/aoyoume/aotuv"
arch=("x86_64")
license=("custom")
 
depends=("libogg>=1.0")
makedepends=("pkgconfig")
conflicts=("libvorbis")
provides=("libvorbis=1.3.2")
 
source=("http://www.geocities.jp/aoyoume/aotuv/source_code/${pkgname}_${pkgver}.tar.bz2"
        "00_vorbis_1.3.2_1.3.4.diff")
sha256sums=("95455420f07e4b3abdf32bda9f5921e9ed3f1afdc3739098dc090150a42fd7fd"
            "10075232433076e5d7cb8db65ec07b35ae446f8f7adeaa6dbc59001dd3408ccc")
 
build() {
 
  cd ${srcdir}/aotuv-${pkgver}_${_releasedate}
  for patch in ${srcdir}/[0-9][0-9]*.diff; do
    msg "Applying ${patch}"
    patch -Np1 -i ${patch}
  done
  chmod +x configure
  ./configure --prefix=/usr --disable-oggtest
  make
 
}
 
package() {
 
  cd ${srcdir}/aotuv-${pkgver}_${_releasedate}
  make DESTDIR=${pkgdir} install
  install -v -m 644 -D ${srcdir}/aotuv-${pkgver}_${_releasedate}/COPYING ${pkgdir}/usr/share/licenses/${pkgname}/COPYING
 
}