Username: Password: Remember me
# Maintainer: Francesco Marinucci <franzmari [at] chakralinux [dot] org>
 
pkgname=sysstat
pkgver=12.0.2
pkgrel=1
pkgdesc="A collection of performance monitoring tools (iostat,isag,mpstat,pidstat,sadf,sar)"
arch=('x86_64')
url="http://pagesperso-orange.fr/sebastien.godard/"
license=('GPL')
depends=('lm_sensors')
makedepends=('systemd')
optdepends=('tk: to use isag'
	    'gnuplot: to use isag')
options=('zipman')
backup=('etc/conf.d/sysstat'
	'etc/conf.d/sysstat.ioconf')
source=("http://pagesperso-orange.fr/sebastien.godard/$pkgname-$pkgver.tar.xz"
	      'lib64-fix.patch')
sha512sums=('c55c3fb8210f006f70e56c8ef5fe013ad1a9247125e69302f920592288725f76ba268c142f1da6ef078a3cdf75e471921ff41aa8b59b8edff57d3bc5345d36e9'
            '46ec3eebb12232d30cddba60f16a57cd8d625513cf002d9e501797a6660f9da9cb4116ec81d0c292644fb6d91eb05c7be458da667260b238bcfef532a020b114')
 
prepare() {
  cd $pkgname-$pkgver
  patch -p1 < ../lib64-fix.patch
  autoreconf
}
 
build() {
  cd $pkgname-$pkgver
  conf_dir=/etc/conf.d ./configure --prefix=/usr \
	--enable-yesterday \
	--mandir=/usr/share/man \
	--enable-install-isag \
	--enable-install-cron \
	--enable-copy-only \
	--disable-man-group
  make
}
 
package() {
  cd $pkgname-$pkgver
  mkdir -p $pkgdir/usr/lib/systemd/system
  make DESTDIR=$pkgdir install
  chown -R root:root $pkgdir
  rm -rf $pkgdir/etc/rc*
}