Username: Password: Remember me
# Maintainer: Max Roder <maxroder@web.de>
# Maintainer: Francesco Marinucci  <franzmari [at] chakraos [dot] org>
 
# To port this PKGBUILD to another language of tor-browser you 
# have to change $pkgname, $_language, $pkgdesc and $url in PKGBUILD
# AND (!) the first line in the .install file!
 
pkgname='tor-browser-it'
pkgver=8.5.5
_realpkgver=$pkgver
_language='it'
pkgrel=1
pkgdesc='Tor Browser Bundle: Anonymous browsing using firefox and tor. Italian version.'
url='https://www.torproject.org/projects/torbrowser.html'
arch=('x86_64')
license=('GPL')
screenshot="http://2.bp.blogspot.com/-en5SOZNUDP0/UfA49xPVwtI/AAAAAAAAAUk/1BNHu5mrtxY/s1600/TorBrowserRunningOnKDE4.png"
depends=('gtk2' 'mozilla-common' 'libxt' 'startup-notification' 'mime-types'
         'dbus-glib' 'alsa-lib' 'desktop-file-utils' 'hicolor-icon-theme'
         'libvpx' 'icu' 'libevent' 'nss' 'hunspell' 'sqlite3')
optdepends=('zenity: simple dialog boxes'
            'kdebase-kdialog: KDE dialog boxes'
            'gst-plugins-good: h.264 video'
            'gst-libav: h.264 video'
            'libpulse: PulseAudio audio driver'
            'libnotify: Gnome dialog boxes')
install="${pkgname}.install"
 
validpgpkeys=('EF6E286DDA85EA2A4BA7DE684E2C6E8793298290')
 
source=("https://www.torproject.org/dist/torbrowser/$pkgver/tor-browser-linux64-${pkgver}_${_language}.tar.xz"{,.asc}
	 "${pkgname}.desktop"
         "${pkgname}.png"
         "${pkgname}.sh")
 
sha256sums=('2c717015170a4131425a99f8a8d73223d45d16bb3ef80ae6276f6c70cbb863b5'
            'SKIP'
            '3d5fc01f2cfbae0a00b7117b0b0a24028d1686e6f81a347809f74de2d8522ff7'
            '17fc2f5784d080233aca16e788d62ab6fe3e57cf781b123cfe32767de97d6d3b'
            '89ed1cda6611abcbfdafef9aec78ada146643455d6675b22b72319ae286ea67e')
 
noextract_x86_64=("tor-browser-linux64-${pkgver}_${_language}.tar.xz")
 
 
package() {
   cd "${srcdir}"
 
   sed -i "s/REPL_NAME/${pkgname}/g"       ${pkgname}.sh
   sed -i "s/REPL_VERSION/${pkgver}/g"	    ${pkgname}.sh
   sed -i "s/REPL_LANGUAGE/${_language}/g" ${pkgname}.sh
 
   sed -i "s/REPL_NAME/${pkgname}/g"       ${pkgname}.desktop
   sed -i "s/REPL_LANGUAGE/${_language}/g" ${pkgname}.desktop
   sed -i "s/REPL_COMMENT/${pkgdesc}/g"    ${pkgname}.desktop
 
   install -Dm 644 ${pkgname}.desktop      ${pkgdir}/usr/share/applications/${pkgname}.desktop
   install -Dm 644 ${pkgname}.png          ${pkgdir}/usr/share/pixmaps/${pkgname}.png
   install -Dm 755 ${pkgname}.sh           ${pkgdir}/usr/bin/${pkgname}
 
   install -Dm 644 tor-browser-linux64-${pkgver}_${_language}.tar.xz ${pkgdir}/opt/${pkgname}/tor-browser-linux64-${pkgver}_${_language}.tar.xz
 
}