Username: Password: Remember me
# Maintainer: Michael Haesel <michael[dot]haesel[at]gmail[dot]com>
# Contributor: Salan54 <salan at fremenil dot com>
 
pkgname=zulucrypt
_pkgname=zuluCrypt
pkgver=5.1.0
pkgrel=1
pkgdesc="A cli and gui frontend to cryptsetup."
arch=('x86_64')
url="http://mhogomchungu.github.io/zuluCrypt"
screenshot="http://i65.tinypic.com/1ak4i.png"
license=('GPL')
depends=('cryptsetup' 'qt5-base' 'libpwquality' 'tcplay' 'libsecret' 'kwalletmanager' 'libxkbcommon-x11')
makedepends=('cmake')
options=('!buildflags')
changelog=${pkgname}.changelog
source=("https://github.com/mhogomchungu/${_pkgname}/releases/download/${pkgver}/${_pkgname}-${pkgver}.tar.bz2")
sha256sums=('dd57be9bcee64f7f4427f4a80e31bf8796d3ad7889f6c3bd78597ff14c1ba520')
 
build() {
  cd ${_pkgname}-${pkgver}
  [ -d build ] || mkdir build && cd build
  cmake \
	-DCMAKE_INSTALL_PREFIX=/usr \
    -DLIB_SUFFIX=lib \
    -DNOGUI=false \
    -DQT5=true \
    -DHOMEMOUNTPREFIX=false \
    -DNOGNOME=true \
    -DUDEVSUPPORT=true \
    -DCMAKE_BUILD_TYPE=release \
    . ..
  make
}
 
package() {
  cd ${_pkgname}-${pkgver}
  install -Dm644 changelog ../${pkgname}.changelog
  cd build
  make DESTDIR="${pkgdir}" install
  install -dm755 "${pkgdir}/etc/modules-load.d"
  echo 'loop' > "${pkgdir}/etc/modules-load.d/${pkgname}.conf"
}